home *** CD-ROM | disk | FTP | other *** search
/ Softdisk Supreme / Softdisk Supreme.iso / pc / DSK Files / 0-49 / SD012a.dsk / THE MUSES.bas < prev    next >
BASIC Source File  |  2003-06-12  |  6KB  |  188 lines
  1. 100  TEXT : HOME : CLEAR 
  2. 110  REM  PROGRAM LENGTH=3500
  3. 120  REM <CTRL-M><CTRL-M>==================<CTRL-M>PAUL RAYMER<CTRL-M>BOX 42831<CTRL-M>LAS VEGAS NV 89116<CTRL-M>==================<CTRL-J>
  4. 130  REM 
  5. 140  REM  PAUL RAYMER'S
  6. 150  REM  MYTHOLOGY
  7. 160  REM  TABLEAUX
  8. 170  REM 
  9. 180  REM  9 MUSES
  10. 190  REM 
  11. 200  REM  XII/XXVI/MCMLXXXI
  12. 210  REM  (C)1982 PEC<CTRL-J>
  13. 220 FUN = 1323
  14. 230  GOTO 270
  15. 240  REM 
  16. 250  FOR Z = 1 TO 1000: NEXT Z: RETURN 
  17. 260  REM 
  18. 270  REM  MAKE BOXES
  19. 280  REM 
  20. 290  INVERSE 
  21. 300  FOR X = 1 TO 24
  22. 310  VTAB X: HTAB 13: PRINT " ";
  23. 320  VTAB X: HTAB 27: PRINT " ";
  24. 330  NEXT X
  25. 340  FOR X = 1 TO 40
  26. 350  VTAB 8: HTAB X: PRINT " ";
  27. 360  VTAB 16: HTAB X: PRINT " ";
  28. 370  NEXT X
  29. 380  NORMAL 
  30. 1000  REM 
  31. 1010  REM  CLIO
  32. 1020  REM 
  33. 1030  VTAB 1: HTAB 2: PRINT "CLIO"
  34. 1040  VTAB 3: HTAB 2: PRINT "MUSE OF";: VTAB 4: HTAB 5: HTAB 2: PRINT "HISTORY";
  35. 1050 V = 0:H = 0: GOSUB 10000
  36. 1060 R =  INT(1000 * RND(1)) +1:R1 =  INT(100 * RND(1)) +1
  37. 1070  VTAB 4: HTAB 2: PRINT R;" B.C.";
  38. 1080  VTAB 5: HTAB 2: PRINT "TO";
  39. 1090  VTAB 6: HTAB 2: PRINT R1;" B.C."
  40. 1100  GOSUB 250
  41. 2000  REM 
  42. 2010  REM  EUTERPE 
  43. 2020  REM 
  44. 2030  VTAB 1: HTAB 15: PRINT "EUTERPE";
  45. 2040  VTAB 3: HTAB 15: PRINT "MUSE OF";
  46. 2050  VTAB 4: HTAB 15: PRINT "THE FLUTE";
  47. 2060 V = 0:H = 13: GOSUB 10000
  48. 2070  FOR X = 2 TO 6: VTAB X: HTAB 15: PRINT "-----------";: NEXT X
  49. 2080  FOR X = 16 TO 25
  50. 2090 R =  INT(5 * RND(1)) +2
  51. 2100  HTAB X: VTAB R: PRINT "O";
  52. 2110  FOR Z = 1 TO 75: NEXT Z
  53. 2120  NEXT X
  54. 2130  GOSUB 250
  55. 3000  REM 
  56. 3010  REM  THALIA
  57. 3020  REM 
  58. 3030  VTAB 1: HTAB 29: PRINT "THALIA";
  59. 3040  VTAB 3: HTAB 29: PRINT "MUSE OF";
  60. 3050  VTAB 4: HTAB 29: PRINT "COMEDY";
  61. 3060 V = 0:H = 27: GOSUB 10000
  62. 3070  VTAB 3: HTAB 31: PRINT "O";: HTAB 35: PRINT "O";
  63. 3080  VTAB 5: HTAB 30: PRINT "+";: HTAB 36: PRINT "+";
  64. 3090  VTAB 6: HTAB 30: PRINT "+-----+";
  65. 3100  VTAB 4: HTAB 33: PRINT  CHR$(34);
  66. 3110  GOSUB 250
  67. 4000  REM 
  68. 4010  REM  MELPOMENE
  69. 4020  REM 
  70. 4030  VTAB 9: HTAB 2: PRINT "MELPOMENE";
  71. 4040  VTAB 11: HTAB 2: PRINT "MUSE OF";
  72. 4050  VTAB 12: HTAB 2: PRINT "TRAGEDY";
  73. 4060 V = 8:H = 0: GOSUB 10000
  74. 4070  VTAB 11: HTAB 4: PRINT "0";: HTAB 8: PRINT "0";
  75. 4080  VTAB 13: HTAB 3: PRINT "+-----+";
  76. 4090  VTAB 14: HTAB 3: PRINT "+     +";
  77. 4100  VTAB 12: HTAB 6: PRINT  CHR$(34);
  78. 4110  GOSUB 250
  79. 5000  REM 
  80. 5010  REM  TERPSICHORE
  81. 5020  REM 
  82. 5030  VTAB 9: HTAB 15: PRINT "TERPISCHORE";
  83. 5040  VTAB 11: HTAB 15: PRINT "MUSE OF";
  84. 5050  VTAB 12: HTAB 15: PRINT "THE DANCE";
  85. 5060  GOSUB 250
  86. 5070 V = 8:H = 13: GOSUB 10000
  87. 5080  VTAB 11: HTAB 14
  88. 5090  POKE 34,10: POKE 35,14: POKE 32,14: POKE 33,11
  89. 5100 A$ = " GAVOTTE    WALTZ      ONE-STEP   TANGO      BOOGIE     SWING      TWIST      ROCK-N-ROLL"
  90. 5110  FOR X = 1 TO  LEN(A$): PRINT  MID$ (A$,X,1);
  91. 5120  FOR Z = 1 TO 50: NEXT Z
  92. 5130  NEXT X
  93. 5140  TEXT 
  94. 5150  GOSUB 250
  95. 6000  REM 
  96. 6010  REM  ERATO
  97. 6020  REM 
  98. 6030  VTAB 9: HTAB 29: PRINT "ERATO";
  99. 6040  VTAB 11: HTAB 29: PRINT "MUSE OF";
  100. 6050  VTAB 12: HTAB 29: PRINT "POETRY";
  101. 6060  GOSUB 250
  102. 6070 V = 8:H = 27: GOSUB 10000
  103. 6080 R =  INT(3 * RND(1)) +1
  104. 6090  IF R = 1  THEN P$ = "TUNE":R$ = "SOON"
  105. 6100  IF R = 2  THEN P$ = "CROON":R$ = "SPOON"
  106. 6110  IF R = 3  THEN P$ = "MOON":R$ = "JUNE"
  107. 6120  VTAB 11: HTAB 29: PRINT P$;
  108. 6130  VTAB 12: HTAB 29: PRINT R$;
  109. 6140  GOSUB 250
  110. 7000  REM 
  111. 7010  REM  POLYHYMNIA
  112. 7020  REM 
  113. 7030  VTAB 17: HTAB 2: PRINT "POLYHYMNIA"
  114. 7040  VTAB 19: HTAB 2: PRINT "MUSE OF"
  115. 7050  VTAB 20: HTAB 2: PRINT "MIMIC ART"
  116. 7060 V = 16:H = 0: GOSUB 10000
  117. 7070  VTAB 20: HTAB 4: PRINT "O    0";
  118. 7080  VTAB 21: HTAB 3: PRINT "-:-  =!=";
  119. 7090  VTAB 22: HTAB 4: PRINT "H    M";
  120. 7100  GOSUB 250
  121. 7110  VTAB 19: HTAB 2: PRINT "??????????";
  122. 7120  GOSUB 250
  123. 7130  SPEED= 50
  124. 7140  VTAB 20: HTAB 9: PRINT "O";
  125. 7150  GOSUB 250
  126. 7160  VTAB 21: HTAB 8: PRINT "-:-";
  127. 7170  GOSUB 250
  128. 7180  VTAB 22: HTAB 9: PRINT "H";
  129. 7190  GOSUB 250
  130. 7200  VTAB 19: HTAB 2: PRINT "          ";
  131. 7210  SPEED= 255
  132. 7220  GOSUB 250
  133. 8000  REM 
  134. 8010  REM  URANIA
  135. 8020  REM 
  136. 8030  VTAB 17: HTAB 15: PRINT "URANIA"
  137. 8040  VTAB 19: HTAB 15: PRINT "MUSE OF"
  138. 8050  VTAB 20: HTAB 15: PRINT "ASTRONOMY"
  139. 8060 V = 16:H = 13: GOSUB 10000
  140. 8070  GOSUB 250
  141. 8080  VTAB 18: HTAB 15
  142. 8090  POKE 34,18: POKE 32,14: POKE 33,11
  143. 8100  HOME 
  144. 8110  SPEED= 100
  145. 8120  INVERSE 
  146. 8130  DIM M$(12)
  147. 8140  FOR X = 1 TO 12: READ M$(X): NEXT X
  148. 8150  FOR K = 1 TO 12
  149. 8160 R =  INT(12 * RND(1)) +1
  150. 8170  IF M$(R) = "ZODIAC"  THEN 8160
  151. 8180  IF K = 10  THEN  NORMAL 
  152. 8190  PRINT M$(R);
  153. 8200  INVERSE 
  154. 8210 M$(R) = "ZODIAC"
  155. 8220  NEXT K
  156. 8230  DATA   ...ARIES...,...TAURUS..,...GEMINI..,...CANCER..,....LEO....,...VIRGO...
  157. 8240  DATA  ...LIBRA...,..SCORPIO..,SAGITTARIUS,.CAPRICORN.,..AQUARIUS.,...PISCES..
  158. 8250  SPEED= 255
  159. 8260  TEXT 
  160. 8270  NORMAL 
  161. 8280  GOSUB 250
  162. 9000  REM 
  163. 9010  REM  CALLIOPE
  164. 9020  REM 
  165. 9030  VTAB 17: HTAB 29: PRINT "CALLIOPE"
  166. 9040  VTAB 19: HTAB 29: PRINT "MUSE OF"
  167. 9050  VTAB 20: HTAB 29: PRINT "ELOQUENCE"
  168. 9060 V = 16:H = 27: GOSUB 10000
  169. 9070 R =  INT(4 * RND(1)) +1
  170. 9080  ON R GOTO 9090,9100,9110,9120
  171. 9090 E1$ = "FOURSCORE":E2$ = "AND SEVEN":E3$ = "YEARS":E4$ = "AGO...": GOTO 9130
  172. 9100 E1$ = "WE":E2$ = "THE":E3$ = "PEOPLE":E4$ = "----": GOTO 9130
  173. 9110 E1$ = "GALLIA":E2$ = "EST":E3$ = "OMNIS":E4$ = "DIVISA": GOTO 9130
  174. 9120 E1$ = "TO BE":E2$ = "OR":E3$ = "NOT":E4$ = "TO BE"
  175. 9130  VTAB 19: HTAB 29: PRINT  CHR$(34);E1$;
  176. 9140  VTAB 20: HTAB 30: PRINT E2$;
  177. 9150  VTAB 21: HTAB 30: PRINT E3$;
  178. 9160  VTAB 22: HTAB 30: PRINT E4$; CHR$(34);
  179. 9170  POKE FUN,48: POKE FUN +4,48
  180. 9180  VTAB 23: HTAB 1
  181. 9190  PRINT D$: PRINT  CHR$(4);"RUN MYTHMENU"
  182. 10000  GOSUB 250
  183. 10010  FOR W = 2 +V TO 7 +V
  184. 10020  FOR WW = 1 +H TO 12 +H
  185. 10030  VTAB W: HTAB WW: PRINT " ";
  186. 10040  NEXT WW: NEXT W
  187. 10050  GOSUB 250
  188. 10060  RETURN